abs.sh

#!/bin/tcsh
# Automatic Backup System. Requires: zenity, pluma, caja.

# Get settings from env. vars. or assign the defaults to them
set default_list_dir = ~/abs/
if ( ${?LIST_FILE} == 0 ) then
       setenv LIST_FILE ${default_list_dir}abs.conf

       echo '(WW) The LIST_FILE environment variable not found'
       echo "     Default used: $LIST_FILE"
       echo '     This is a path to file with a list of files to backup'
       echo '     Use `setenv LIST_FILE /path/to/file` to override the default'
endif
if ( ${?BACKUPS_DIR} == 0 ) then
       setenv BACKUPS_DIR ${default_list_dir}backups/

       echo '(WW) The BACKUPS_DIR environment variable not found'
       echo "     Default used: $BACKUPS_DIR"
       echo '     This is a path to directory for storing backup archives'
       echo '     Use `setenv BACKUPS_DIR /path/to/dir/` to override the default'
endif
if ( ${?TEXT_EDITOR} == 0 ) then
       setenv TEXT_EDITOR pluma

       echo '(WW) The TEXT_EDITOR environment variable not found'
       echo "     Default used: $TEXT_EDITOR"
       echo '     This variable sets a text editor for editing the configuration'
       echo '     Use `setenv TEXT_EDITOR editor` to override the default'
endif
if ( ${?FILE_MANAGER} == 0 ) then
       setenv FILE_MANAGER caja

       echo '(WW) The FILE_MANAGER environment variable not found'
       echo "     Default used: $FILE_MANAGER"
       echo '     This variable sets a file manager to view backups directory'
       echo '     Use `setenv FILE_MANAGER nautilus` to override the default'
endif

# Getting dependencies tools
set DIALOG = zenity

# Build the name for the backup
set timestamp = `date +%Y_%m_%d-%H%M`
set targets = "/tmp/$timestamp.abs"
set archive = "$BACKUPS_DIR/$timestamp.cpio"

set found = ( )
set missing = ( )

# Add a warning for a user about unavailable list of files for backing up
set text = ''
if ( ! -r $LIST_FILE ) then
       mkdir -p $default_list_dir
       touch "$LIST_FILE"
       chmod g+w "$LIST_FILE"

       set text = "${text}"'\<span\ foreground=\"blue\"\>Unable\ to\ find\ $LIST_FILE!\ Use:\\n'
       set text = "${text}"'setenv\ LIST_FILE\ /path/to/file\\n'
       set text = "${text}"'to\ point\ to\ the\ list\ of\ files\ for\ backing\ up.\\n\\n\</span\>'
endif

# Building lists of found and missing targets for backing up
foreach target ( `cat "$LIST_FILE"` )
       if ( -e $target ) then
              set found = ( $found $target )
       else
              set missing = ( $missing $target )
       endif
end

# Expanding the list of found backup targets
# (list all files from dirs specified in abs.conf)
rm -f $targets
foreach found_target ( $found )
       find "$found_target" -print >> $targets
end

# Even there are no files to back up, I will create the directory for them
# for a case when user interested in viewing the empty directory for backups
mkdir -p $BACKUPS_DIR

if ( -r $targets ) then
       # Creating the archive
       cat $targets | cpio -o > $archive
       rm $targets

       # Build a message for users owning graphical displays
       set text = "${text}Backed\ up:\\n"
       foreach f ( $found )
              set text = "$text\ \ \ \ \ \ \ $f\\n"
       end
       set text = "$text\\nMissing:\\n"
       foreach m ( $missing )
              set text = "$text\ \ \ \ \ \ \ $m\\n"
       end
else
       set text = "${text}"'\<span\ foreground=\"red\"\>Nothing\ to\ backup.\ '
       set text = "${text}"'Check\ the\ invocation.\ The\ sample\ is\ below.\\n'
       set text = "${text}"'setenv\ LIST_FILE\ /etc/abc.conf\ \;\ setenv\ BACKUPS_DIR\ /mnt/bkup/\ \;\ ./abs\</span\>'
endif

# Loop over all users logged in to graphical sessions
foreach name ( `users` )
       # Get login information and remove all except the display from it
       set display = `lastlogin "$name"`
       set display = `echo "$display" | sed "s/$name//g"`
       set display = `echo "$display" | sed 's/pts\/[0-9]*//g'`
       set display = `echo "$display" | sed 's/ttyv[0-9]*//g'`
       set display = `echo "$display" | sed 's/[A-Z][a-z][a-z][ ]*[A-Z][a-z][a-z][ ]*[0-9]*[ ]*[0-9]*:[0-9][0-9]:[0-9][0-9][ ]*[0-9]*//g'`

       # Skip notifying this user if the display wasn't found
	   if ( '0' == "${%display}" ) then
			  continue
	   endif

       # Inform a user that backups are done
       # and allow users to view backups and
       # add new files to the list of backing up files
       set action = `su $name -c $DIALOG\ --timeout=22\ --info\ --text="$text"\ --display="$display"\ --extra-button='View'\ --title='Automatic\ Backup\ System'\ --extra-button='Configure'`
       switch ("$action")
              case 'View': # View all backups
                     su $name -c $FILE_MANAGER\ --display="$display"\ $BACKUPS_DIR\ &
              breaksw
              case 'Configure': # Configure backing up files
                     su $name -c $TEXT_EDITOR\ --display="$display"\ $LIST_FILE\ &
              breaksw
       endsw
end
#!/bin/tcsh

setenv LIST_FILE   /root/abs/abs.conf
setenv BACKUPS_DIR /mnt/barracuda/backups/
setenv TEXT_EDITOR /usr/local/bin/editor

set LOG_FILE     = ${BACKUPS_DIR}.log

echo "`date`: run" >> ${LOG_FILE}

set TYPESCRIPT_DIR = /tmp/abs/
set TYPESCRIPT_FILE = ${TYPESCRIPT_DIR}abs.log

mkdir -p ${TYPESCRIPT_DIR}
script ${TYPESCRIPT_FILE} /root/abs/abs
cat -n ${TYPESCRIPT_FILE} >> ${LOG_FILE}

echo "`date`: end" >> ${LOG_FILE}